Alguem já fez Player de Video em JavaFX?

package playerdevideo;

import javafx.stage.Stage;
import javafx.scene.Scene;
import javafx.scene.media.*;
import javafx.scene.layout.*;
import javafx.scene.control.Button;
import javafx.scene.control.TextBox;
import javafx.scene.control.Label;

var videoUrl: TextBox;
var btnPlay: Button;
var mensagem: String = "Entre uma URL";
def mediaPlayer = MediaPlayer {
            onError: function (e) {
                mensagem = "Um erro ocorreu: \n {e}";
            }         
        };
def mediaView = MediaView {            
            mediaPlayer: mediaPlayer;
        }
def barraSuperior =
        HBox {
            spacing: 10;
            content: [
                videoUrl = TextBox {
                            promptText: "Entre a URL do vídeo aqui"
                        }
                btnPlay = Button {
                            text: ">"
                            action: function () {
                                if (videoUrl.text != "") {
                                    try {
                                        mediaPlayer.stop();
                                        mediaPlayer.media = Media {source: videoUrl.text }
                                        mediaPlayer.play();
                                    } catch (e) {
                                        mensagem = "Um erro ocorreu, verifique sua URL: \n {e}";
                                    }
                                }
                            }
                        }
            ]
        }

Stage {
    title: "Simples Media Player em JavaFX"
    scene: Scene {        
        content: [
            VBox {
                layoutInfo: LayoutInfo{width:800 height: 600}
                content: [
                    barraSuperior,
                    Stack {
                        content: [
                            mediaView,
                            Label {
                                visible: bind mediaPlayer.paused;
                                text: bind mensagem
                            }
                        ]
                    }
                ]
            }
        ]
    }
}