Cansado da janela preta do prompt de comando aberta após

@echo off
rem Arquivo Batch para rodar um .jar no Windows

rem Remover "rem" das duas linhas abaixo para usar o j2sdk.
rem set JAVA_HOME=C:\j2sdk1.4.2_06
rem set PATH=%JAVA_HOME%\bin

set MICROAGENDA_JAR=MicroAgenda.jar
set INITIAL_HEAP_SIZE=16m
set MAXIMUM_HEAP_SIZE=384m
set STACK_SIZE=2m

rem MICROAGENDA_HOME deve estar nessa pasta
if not "%MICROAGENDA_HOME%"=="" goto hasMicroAgendaHome

if "%OS%"=="Windows_NT" goto setMicroAgendaHomeNT

rem *** Usuario do Windows98 tem que editar aqui ****
rem set MICROAGENDA_HOME=c:\Program Files\MicroAgenda

if "%MICROAGENDA_HOME%"=="" goto noMicroAgendaHome
if not exist "%MICROAGENDA_HOME%\%MICROAGENDA_JAR%" goto badMicroAgendaHome
goto hasMicroAgendaHome

rem para Windows2000, XP, NT
:setMicroAgendaHomeNT
set MICROAGENDA_HOME=%~dp0

:hasMicroAgendaHome

rem set CLASSPATH=%MICROAGENDA_HOME%\%MICROAGENDA_JAR%


set JAVA_OPTS=-Xms%INITIAL_HEAP_SIZE% -Xmx%MAXIMUM_HEAP_SIZE% -Xss%STACK_SIZE%

if exist "%MICROAGENDA_HOME%\jre\bin\javaw.exe" set PATH="%MICROAGENDA_HOME%\jre\bin"

rem executar MicroAgenda
start javaw %JAVA_OPTS% -jar "%MICROAGENDA_HOME%\%MICROAGENDA_JAR%"  %1 %2 %3
goto end

:noMicroAgendaHome
echo.
echo MICROAGENDA_HOME não está definido.  Por favor, ajuste a variável de
echo ambiente MICROAGENDA_HOME ou edite o MicroAgenda.bat para definir a var MICROAGENDA_HOME
echo. 
pause
goto end

:badMicroAgendaHome
echo.
echo MICROAGENDA_HOME é inválido.  Por favor, verifique a variável de ambiente
echo MICROAGENDA_HOME.
echo. 
pause
goto end

:end